home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
NEW
/
V-TPUG Programming Contest
/
(n)v1.d64
/
zip
(
.txt
)
< prev
Wrap
Commodore BASIC
|
2009-01-19
|
2KB
|
100 lines
10 PRINT"[147]"
13 IN=4*(PEEK(36866)AND128)
15 SP=IN+64*(PEEK(36869)AND112)
17 CL=37888+IN
40 C=CL-SP:TB=0:TS=0
50 POKE36879,239
95 DIM SE(44)
96 ES=SP+512
120 PRINTTAB(5)"DIRECTIONS"
130 PRINTTAB(5)"7777777777"
140 PRINT" YOU WILL HAVE 2 MIN.":PRINT"TO GET YOUR BEST SCORE"
150 PRINT"[158]MOVEMENT:":PRINT"CRSR DN=LEFT":PRINT"CRSR RT=RIGHT":PRINT"F5=UP"
160 PRINT"F7=DOWN":PRINT""
170 PRINTTAB(14)"SCORING:"
180 PRINTTAB(14)"[144]W=1"
190 PRINTTAB(14)"[159]Q=2"
200 PRINTTAB(14)"[158]Z=3"
210 PRINTTAB(14)"S=5"
220 PRINTTAB(14)"A=10"
230 PRINT "YOU ARE: [146]"
240 PRINT"DON'T HIT A [156]* OR":PRINT "YOU WILL GET [156] ZAPPED."
250 PRINT"PRESS ANY KEY TO START"
260 GETA$:IFA$=""THEN 260
270 PRINT"[147]"
330 PRINT"WHAT SKILL LEVEL?"
340 PRINT"PRESS 0,1,2,3 OR 4";
350 INPUT S
360 IF S>4 ORS<0THENPRINT"HUH?":GOTO340
390 PRINT"[147]"
400 DEF FN A(L)=INT(RND(1)*L)+SP+22
410 FORF=1TO40-2*S:D=FNA(483)
420 POKED,87:POKED+C,0:NEXTF
430 FORF=1TO25:D=FNA(483)
440 POKED,81:POKED+C,3:NEXTF
450 FORF=1TO10+4*S:D=FNA(505)
455 IF D>ES THEN SE(D-ES)=42:GOTO465
460 POKED,42:IF D>SP THEN POKED+C,4
465 NEXT F
470 FORF=1TO19:D=FNA(483)
480 POKED,90:POKED+C,7:NEXTF
490 FORF=1TO14:D=FNA(483)
500 POKED,83:POKED+C,2:NEXTF
510 FORF=1TO9+S:D=FNA(505)
515 IF D>ES THEN SE(D-ES)=65:GOTO 525
520 POKE D,65:IF D>SP THEN POKED+C,1
525 NEXT F
530 B=SP+252
540 TI$="000000"
550 PRINT"TIME:";120-INT(TI/60);"[157] "
560 IFTI/60>=120THENGOTO930
570 IF B<ES THEN POKEB,160:IF B>SP THEN POKEB+C,6
580 IF B<SP-44 THEN B=B+594
585 IFB>SP+549THENB=B-594
590 IFPEEK(197)=31THENH=190:DR=-1:GOTO630
600 IFPEEK(197)=23THENH=200:DR=1:GOTO630
610 IFPEEK(197) =55THENH=210:DR=-22:GOTO630
620 IFPEEK(197)=63THENH=220:DR=22
630 POKE36878,15:POKE36876,H
640 FORT=1TO30-5*S:NEXTT
650 IF B<ES THEN POKEB,32
655 B=B+DR
660 SC=0
662 IF B<ES THEN 670
664 IF SE(B-ES)=42 THEN 790
666 IF SE(B-ES)=65 THEN SC=10:GOTO 740
670 IFPEEK(B)=42THENGOTO790
680 IFPEEK(B)=87THENSC=1:GOTO740
690 IFPEEK(B)=81THENSC=2:GOTO740
700 IFPEEK(B)=90THENSC=3:GOTO740
710 IFPEEK(B)=83THENSC=5:GOTO740
720 IFPEEK(B)=65THENSC=10:GOTO740
730 GOTO760
740 TS=TS+SC
750 POKE36878,15:POKE 36876,160+PEEK(B)
760 FORT=1TO30-5*S:NEXTT
770 PRINT"SCORE=";TS
780 GOTO550
790 POKE36878,15
800 FORPI=1TO40:POKE36876,180-PI:NEXTPI
810 PRINT"[156]&&&& &&&& &&&&[160]&&[160]&&"
820 PRINT"&&&&[160]&&&&[160]&&&&[160]&&[160]&&"
830 PRINT" &[160]&[160][160]&[160]&[160][160]&[160]&&[160]&&"
840 PRINT" & &&&& &&&& && &&"
850 PRINT" & &&&& &&&& && &&"
860 PRINT"&&&&[160]&[160][160]&[160]&"
870 PRINT"&&&&[160]&[160][160]&[160]&[160][160][160][160]&&[160]&&"
890 POKE36878,0:POKE36876,0
900 FORT=1TO2000:NEXTT:PRINT"[147]"
910 PRINT"YOU LASTED";INT(TI/60)-3;"[157] SECONDS[146]"
920 GOTO970
930 POKE36878,15:FORAC=1TO80:POKE36876,210-AC:NEXTAC
940 POKE36876,0:POKE37878,0
950 PRINT"[147]"
960 PRINT"[147]......TIME IS UP......"
970 PRINTTAB(6)"SCORE=";TS
990 IFTS>TBTHENTB=TS:SL=S:PB=P
1040 TS=0:DR=0:H=0:PRINT"[145]"
1050 GOTO 330
1060 END